{ nixpkgs, nixpkgs-unstable, ... }:
let
  environments = {
    "proxmox" = [
      ./configuration/proxmox-vm
      ./configuration/proxmox-vm/hardware-configuration.nix
    ]; 
  };
  generateDefaults = hosts: builtins.mapAttrs (name: {
    hostNixpkgs ? nixpkgs,
    system ? "x86_64-linux",
    pkgs ? hostNixpkgs.legacyPackages.${system},
    environment ? "proxmox",
    site
  }: {
    inherit hostNixpkgs system pkgs environment site;
    modules = [
      ./configuration/common
      ./hosts/${name}
    ] ++ (if environments ? ${environment} then environments.${environment} else []);
  }) hosts;
in
  generateDefaults {
    hydra = {
      hostNixpkgs = nixpkgs-unstable;
      site = "vs";
    };
    iperf = {
      site = "vs";
    };
    jackett = {
      site = "vs";
    };
    nitter = {
      site = "vs";
    };
    nixos-coturn = {
      site = "vs";
    };
    tor-relay = {
      site = "vs";
    };
    web-public-2 = {
      hostNixpkgs = nixpkgs-unstable;
      site = "vs";
    };
  }